BME280搭載　温湿度・気圧センサモジュールの使い方

特徴

BME280の主な特徴は以下の通りです。

• 1チップで温度・湿度・気圧の3種類の環境情報を取得可能
• I2CとSPI　2種類の通信方法に対応
• 動作電圧が1.8V～3.3V　Edisonなどの1.8V系のI/Oに接続可能

初期設定

次のレジスタマップを見ながらBME280の設定をします。

・configレジスタ（0xF5）は次の項目を設定するためのレジスタです。

• t_sb[2:0] スタンバイ時間
• filter[2:0] IIRフィルタの有効/無効
• spi3w_en[0] 3 wire SPIの有効/無効

スタンバイ時間は次の中から選択します。

スタンバイ時間とはセンサが計測をしないで待機している時間のことです。
今回は例として1000msを選択しました。

IIRフィルタの値は次の中から選択します。

温度と気圧は計測結果を20bitで取得しますが、下位の4bit分(xlsb)は無効です。
IIRフィルタを有効にすると下位4bitも有効になります。しかし、フィルタを有効にすると正しい値を取得するために複数回のサンプリングが必要になります。
フィルタの値が大きいほど必要なサンプリング回数が増えます。
今回は例としてFilter offを選択しました。

BME280は3線式と4線式のSPIに対応しています。
spi3w_en[0]を0にすると4線式、1にすると3線式です。ここでは0にします。

よってconfigレジスタの値は 0b10100000 0xA0に決まりました。

・ctrl_measレジスタ（0xF4）は次の項目を設定するためのレジスタです。

• osrs_t[2:0] 温度測定の有効（オーバーサンプリング値）/無効
• osrs_p[2:0] 気圧測定の有効（オーバーサンプリング値）/無効
• mode[1:0] BME280の測定モード設定

温度測定の有効/無効は次のように設定します。

無効にすると結果は0x80000に固定されます。
オーバーサンプリングをすることでノイズによる測定結果への影響を軽減することができますが、測定時間が増加します。
今回は例としてoversampling x 1を選択しました。

気圧測定の有効/無効は次のように設定します。

無効にすると結果は0x80000に固定されます。
オーバーサンプリングをすることでノイズによる測定結果への影響を軽減することができますが、測定時間が増加します。
今回は例としてoversampling x 1を選択しました。

BME280のモード設定は次の中から選びます。

モードは Sleep、Forced、Normalの三つです。
Sleepは計測をしないモード、電源を入れてすぐはSleepモードです。
Forcedモードは1度だけ測定を行うモードです。測定を行うと自動的にSleepモードに戻ります。
Normalモードは繰り返し測定を行うモードです。測定を繰り返す間隔は温度・湿度・気圧の測定時間とスタンバイ時間を合わせた時間です。
今回の例ではNormalモードを使用します。

よってctrl_measレジスタの値は　0b00100111 0x27に決まりました。

・ctrl_humレジスタ（0xF2）

• osrs_h[2:0] 湿度測定の有効（オーバーサンプリング値）/無告

　 湿度測定の有効/無効は次のように設定します。

無効にすると結果は0x80000に固定されます。
オーバーサンプリングをすることでノイズによる測定結果への影響を軽減することができますが、測定時間が増加します。
今回は例としてoversampling x 1を選択しました。

よってctrl_humレジスタの値は 0b00000001 0x01に決まりました。

使い方

レジスタの設定値が決定したので値をレジスタに書込み測定を開始します。
気圧の情報はレジスタのアドレス　0xF7 0xF8 0xF9に格納されます。
温度の情報はレジスタのアドレス　0xFA 0xFB 0xFCに格納されます。
湿度の情報はレジスタのアドレス　0xFD 0xFE に格納されます。　湿度だけ2byteです。

温度・湿度・気圧の補正をするための値がアドレス0x88～0xA1 0xE1～0xF0に格納されています。
以上の情報を元にサンプルスケッチを書いてみました。

I2Cの場合

基板上にI2C用のプルアップ抵抗が実装されていないので、使用する場合にはプルアップ抵抗を用意する必要があります。

サンプルスケッチ

#include <Wire.h>

#define BME280_ADDRESS 0x76
unsigned long int hum_raw,temp_raw,pres_raw;
signed long int t_fine;

uint16_t dig_T1;
 int16_t dig_T2;
 int16_t dig_T3;
uint16_t dig_P1;
 int16_t dig_P2;
 int16_t dig_P3;
 int16_t dig_P4;
 int16_t dig_P5;
 int16_t dig_P6;
 int16_t dig_P7;
 int16_t dig_P8;
 int16_t dig_P9;
 int8_t  dig_H1;
 int16_t dig_H2;
 int8_t  dig_H3;
 int16_t dig_H4;
 int16_t dig_H5;
 int8_t  dig_H6;

void setup()
{
    uint8_t osrs_t = 1;             //Temperature oversampling x 1
    uint8_t osrs_p = 1;             //Pressure oversampling x 1
    uint8_t osrs_h = 1;             //Humidity oversampling x 1
    uint8_t mode = 3;               //Normal mode
    uint8_t t_sb = 5;               //Tstandby 1000ms
    uint8_t filter = 0;             //Filter off 
    uint8_t spi3w_en = 0;           //3-wire SPI Disable
    
    uint8_t ctrl_meas_reg = (osrs_t << 5) | (osrs_p << 2) | mode;
    uint8_t config_reg    = (t_sb << 5) | (filter << 2) | spi3w_en;
    uint8_t ctrl_hum_reg  = osrs_h;
    
    Serial.begin(9600);
    Wire.begin();
    
    writeReg(0xF2,ctrl_hum_reg);
    writeReg(0xF4,ctrl_meas_reg);
    writeReg(0xF5,config_reg);
    readTrim();                    //
}


void loop()
{
    double temp_act = 0.0, press_act = 0.0,hum_act=0.0;
    signed long int temp_cal;
    unsigned long int press_cal,hum_cal;
    
    readData();
    
    temp_cal = calibration_T(temp_raw);
    press_cal = calibration_P(pres_raw);
    hum_cal = calibration_H(hum_raw);
    temp_act = (double)temp_cal / 100.0;
    press_act = (double)press_cal / 100.0;
    hum_act = (double)hum_cal / 1024.0;
    Serial.print("TEMP : ");
    Serial.print(temp_act);
    Serial.print(" DegC  PRESS : ");
    Serial.print(press_act);
    Serial.print(" hPa  HUM : ");
    Serial.print(hum_act);
    Serial.println(" %");    
    
    delay(1000);
}
void readTrim()
{
    uint8_t data[33],i=0;
    Wire.beginTransmission(BME280_ADDRESS);
    Wire.write(0x88);
    Wire.endTransmission();
    Wire.requestFrom(BME280_ADDRESS,25);
    while(Wire.available()){
        data[i] = Wire.read();
        i++;
    }
    Wire.beginTransmission(BME280_ADDRESS);
    Wire.write(0xE1);
    Wire.endTransmission();
    Wire.requestFrom(BME280_ADDRESS,8);
    while(Wire.available()){
        data[i] = Wire.read();
        i++;    
    }
    dig_T1 = (data[1] << 8) | data[0];
    dig_T2 = (data[3] << 8) | data[2];
    dig_T3 = (data[5] << 8) | data[4];
    dig_P1 = (data[7] << 8) | data[6];
    dig_P2 = (data[9] << 8) | data[8];
    dig_P3 = (data[11]<< 8) | data[10];
    dig_P4 = (data[13]<< 8) | data[12];
    dig_P5 = (data[15]<< 8) | data[14];
    dig_P6 = (data[17]<< 8) | data[16];
    dig_P7 = (data[19]<< 8) | data[18];
    dig_P8 = (data[21]<< 8) | data[20];
    dig_P9 = (data[23]<< 8) | data[22];
    dig_H1 = data[24];
    dig_H2 = (data[26]<< 8) | data[25];
    dig_H3 = data[27];
    dig_H4 = (data[28]<< 4) | (0x0F & data[29]);
    dig_H5 = (data[31] << 4) | ((data[30] >> 4) & 0x0F);
    dig_H6 = data[32];   
}
void writeReg(uint8_t reg_address, uint8_t data)
{
    Wire.beginTransmission(BME280_ADDRESS);
    Wire.write(reg_address);
    Wire.write(data);
    Wire.endTransmission();    
}


void readData()
{
    int i = 0;
    uint32_t data[8];
    Wire.beginTransmission(BME280_ADDRESS);
    Wire.write(0xF7);
    Wire.endTransmission();
    Wire.requestFrom(BME280_ADDRESS,8);
    while(Wire.available()){
        data[i] = Wire.read();
        i++;
    }
    pres_raw = (data[0] << 12) | (data[1] << 4) | (data[2] >> 4);
    temp_raw = (data[3] << 12) | (data[4] << 4) | (data[5] >> 4);
    hum_raw  = (data[6] << 8) | data[7];
}


signed long int calibration_T(signed long int adc_T)
{
    
    signed long int var1, var2, T;
    var1 = ((((adc_T >> 3) - ((signed long int)dig_T1<<1))) * ((signed long int)dig_T2)) >> 11;
    var2 = (((((adc_T >> 4) - ((signed long int)dig_T1)) * ((adc_T>>4) - ((signed long int)dig_T1))) >> 12) * ((signed long int)dig_T3)) >> 14;
    
    t_fine = var1 + var2;
    T = (t_fine * 5 + 128) >> 8;
    return T; 
}

unsigned long int calibration_P(signed long int adc_P)
{
    signed long int var1, var2;
    unsigned long int P;
    var1 = (((signed long int)t_fine)>>1) - (signed long int)64000;
    var2 = (((var1>>2) * (var1>>2)) >> 11) * ((signed long int)dig_P6);
    var2 = var2 + ((var1*((signed long int)dig_P5))<<1);
    var2 = (var2>>2)+(((signed long int)dig_P4)<<16);
    var1 = (((dig_P3 * (((var1>>2)*(var1>>2)) >> 13)) >>3) + ((((signed long int)dig_P2) * var1)>>1))>>18;
    var1 = ((((32768+var1))*((signed long int)dig_P1))>>15);
    if (var1 == 0)
    {
        return 0;
    }    
    P = (((unsigned long int)(((signed long int)1048576)-adc_P)-(var2>>12)))*3125;
    if(P<0x80000000)
    {
       P = (P << 1) / ((unsigned long int) var1);   
    }
    else
    {
        P = (P / (unsigned long int)var1) * 2;    
    }
    var1 = (((signed long int)dig_P9) * ((signed long int)(((P>>3) * (P>>3))>>13)))>>12;
    var2 = (((signed long int)(P>>2)) * ((signed long int)dig_P8))>>13;
    P = (unsigned long int)((signed long int)P + ((var1 + var2 + dig_P7) >> 4));
    return P;
}

unsigned long int calibration_H(signed long int adc_H)
{
    signed long int v_x1;
    
    v_x1 = (t_fine - ((signed long int)76800));
    v_x1 = (((((adc_H << 14) -(((signed long int)dig_H4) << 20) - (((signed long int)dig_H5) * v_x1)) + 
              ((signed long int)16384)) >> 15) * (((((((v_x1 * ((signed long int)dig_H6)) >> 10) * 
              (((v_x1 * ((signed long int)dig_H3)) >> 11) + ((signed long int) 32768))) >> 10) + (( signed long int)2097152)) * 
              ((signed long int) dig_H2) + 8192) >> 14));
   v_x1 = (v_x1 - (((((v_x1 >> 15) * (v_x1 >> 15)) >> 7) * ((signed long int)dig_H1)) >> 4));
   v_x1 = (v_x1 < 0 ? 0 : v_x1);
   v_x1 = (v_x1 > 419430400 ? 419430400 : v_x1);
   return (unsigned long int)(v_x1 >> 12);   
}