nekoboardとnekoboard2の違いについて

​nekoboardはScratch 1.4のみ対応で、​nekoboard2はScratch 1.4と2.0に対応しています。

まずnekoboardはArduino互換ボードなのでArduino IDEでファームウェアの書き込みができるようになっています。Arduino互換機のnekoboardはファームウェアを書き込む直前にFT232RLのDTRの信号をLにすることでリセットをかけています。
リセットがかかった直後のnekoboardはブートローダが起動してファームウェア（スケッチ）の書き込みが可能になります。

この点を踏まえてScratch 1.4でnekoboardを使う際の挙動を書くと次のようになっています。

1. Scratch 1.4では接続したnekoboardのポート番号を手動で選びます。
   
2. ポートが開くとDTRがONになります。
   
3. DTRがONになるとnekoboardのリセットがかかり、ブートローダが起動します。
   
4. しばらくするとブートローダが終了し、ファームウェア本体が起動します。
   
5. Scratch 1.4からの信号を受信すると、nekoboardがセンサーの値を送り返します。
   
6. Scratch 1.4上でセンサーの値が読み取れるようになります。
   

ではScratch 2.0でnekoboardを使うとどうなるかを書くと、次のようになります。

1. 拡張機能を追加でPicoBoardを選択します。
   
2. Scratch 2.0では自動でポート番号を選択します。（一番小さいポート番号が選択されます。）
   
3. ポートを開いて通信を開始します。ポートが開くとDTRがONになります。
   
4. DTRがONになるとnekoboardのリセットがかかり、ブートローダが起動します。
   
5. ブートローダが実行中にScratch 2.0からの信号が送られてきます。
   
6. ブートローダ実行中にはセンサーの値を返信できません。
   
7. 時間内にセンサーの値が送られてこないとScratch 2.0は一度ポートを閉じて、再び接続を試みます。
   
8. 再びnekoboardにリセットがかかり、ブートローダが起動します。
   
9. 以下繰り返しでリセットがかかってしまい、ファームウェア本体が起動しません。
   

この問題を解決するために、nekoboard2ではFT231XSのDTRの信号をリセット線から外してしまいました。
このことによりArduino互換機ではなくなってしまいました。

（nekoboardでもブートローダ無しのファームウェアを書き込めばScratch 2.0対応できると思いますが、この場合もArduinoとしてファームウェアの書換ができない事には変わりありません。）

書き込まれているファームウェア

nekoboard2はArduino互換機ではありませんが、書き込まれているファームウェアはnekoboardのものをほぼそのまま使用しています。
つまりブートローダは書き込まれたままになっていますので、Arduino IDEでコンパイルが終わった直後にうまくリセットをかけることができればArduino IDEでファームウェアを書き換えることも可能です。
（J3と書かれたパッドのRESETとGNDをショートさせればリセットがかかります。）

nekoboard2に書き込まれているファームウェアのスケッチです。

// Scratch sensor board sketch for Arduino bootloader on Nekoboard2
// Switch-Science
// 2016/04/25

int analogPin[4] = { A0,A1,A2,A3 };  // select the input pin for the general analog 0-4
int lightPin = A4;   // select the input pin for the sensor
int micPin = A5;     // select the input pin for the mic
int sliderPin = A6;  // select the input pin for the slide volume
int buttonPin = 2;   // select the pin for the button

int sliderValue = 0; // variable to store the value coming from the slide volume
int lightValue = 0;  // variable to store the value coming from the light sensor
int micValue = 0;    // variable to store the value coming from the mic
int analogValue[4] = { 0,0,0,0};  // variable to store the value coming from the analog 0-4
const int firmware = 0x04; // Firmware virsion

int senddata[18]={ 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0 };

void setsenddata(int value,int channel) {
  int pos;
  byte highdata = 0;
  byte lowdata = 0;
  if (channel==15) {
    pos = 0;
  } else {
    pos = channel*2+2;
  }
  highdata = 0x80 | (channel<<3) | lowByte(value >>7);
  lowdata  = lowByte(0x7f & value);
  senddata[pos] = highdata;
  senddata[pos+1] = lowdata;
}

void setup() {
  // declare the ledPin as an OUTPUT:
  pinMode(buttonPin,INPUT);
  digitalWrite(buttonPin,HIGH);  // プルアップのため
  Serial.begin(38400);
}

void loop() {
  int i;
 // if(1){
  if (Serial.available() > 0) {     // 受信したデータが存在したら
    int inByte = Serial.read();     // 受信データを読み込む
    if (inByte == 0x0001) {         // 送られてきたデータが0x01だったら
      for (int i=0; i<18; i++) {
        Serial.write(senddata[i]);  // 用意されているセンサーデータを送信する
      }
    }

    // read the value from the sensor:
    sliderValue = 1023 - analogRead(sliderPin);
    lightValue = analogRead(lightPin) - 15;
    if(lightValue < 0){
      lightValue = 0;
    }
    micValue = analogRead(micPin);

    for (i=0; i<4; i++) {
      analogValue[i] = analogRead(analogPin[i]);
    }

    // Make sending data
    for (i=0; i<16; i++) {
      switch(i) {
      case 0:
        // Ch0 Registance-D
        setsenddata(analogValue[3],0);
        break;
      case 1:
        // Ch1 Registance-C
        setsenddata(analogValue[2],1);
        break;
      case 2:
        // Ch2 Registance-B
        setsenddata(analogValue[1],2);
        break;
      case 3:
        // Ch3 Button
        if (digitalRead(buttonPin) == 1) {
          setsenddata(1023,3);
        } 
        else {
          setsenddata(0,3);
        } 
        break;
      case 4:
        // Ch4 Registance-A
        setsenddata(analogValue[0],4);
        break;
      case 5:
        // Ch5 Light
        setsenddata(lightValue,5);
        break;
      case 6:
        // Ch6 Sound
        setsenddata(micValue,6);
        break;
      case 7:
        // Ch7 Slider
        setsenddata(sliderValue,7);
        break;
      case 15:
        // Ch15 Firmware ID
        setsenddata(firmware,15);
        break;
      default:
        // Ch8-14 No operation
        break;
      }
    }
  }
}