Changes between Initial Version and Version 1 of MAX31855Sketch

Timestamp:

Feb 15, 2012 11:55:45 AM (12 years ago)

Author:

maris

Comment:

--

MAX31855Sketch

@@ +1 @@
+= MAX6675 K型熱電対温度センサのスケッチ =
+
+ * [wiki:MAX31855 概要についてはこちら。]
+ * [wiki:MAX31855Instruction 作り方の説明はこちら。]
+ * [http://www.switch-science.com/products/detail.php?product_id=864 キットとして販売しています。]
+
+どんなスケッチ（ソフトウェア）で使うのかを説明します。
+
+すでにモジュールが完成していて、Arduino Uno (Arduino Duemilanove) のデジタル8番～13番の位置に差し込んであるものとします。
+
+[attachment:max31855_example.zip このページの添付ファイル「max31855_example.zip」]をダウンロードして、展開します。[[BR]]
+展開してできたフォルダを、Arduinoのスケッチブックのフォルダに移動します。[[BR]]
+スケッチブックのフォルダは、ウィンドウズでは標準は「ドキュメント」（Vista/7の場合）または「マイドキュメント」（XPの場合）の中にある、「Arduino」というフォルダです。
+
+Arduino統合環境を起動して、「ファイル」メニューの「スケッチブック」から「max31855_example」を探して開いてください。
+
+あとは、普通にArduinoに書き込んで実行します。[[BR]]
+「シリアルモニタ」を有効にすると、定期的に温度が表示されます。[[BR]]
+K型熱電対の温度 // 基準接点の温度(max31855の温度)[[BR]]
+「ERROR: 」と表示された場合は、熱電対がきちんとつながっていません。[[BR]]
+続いて「Short to Vcc, 」と表示された場合は、Vcc側とショートしています。[[BR]]
+「Short to GND, 」と表示された場合は、GND側とショートしています。[[BR]]
+「Open Circuit, 」と表示された場合は、K型熱電対が接続されていないか、途中で切れています。
+
+スケッチの先頭に、以下の定義があります。
+{{{
+#!c
+/*
+// Arduinoボードの電源電圧が3.3Vの場合、
+// 以下のマクロを有効にしてモジュールを直挿しできます。
+#define VCC  8
+#define GND  9
+*/
+}}}
+モジュールをデジタルの8番～13番に直結したい場合は、これらの定義を有効にしてください。[[BR]]
+VCCおよびGNDの定義は、デジタルの8番および9番からモジュールに電源供給を行うためです。
+この方法が使えるのはArduinoの電源電圧が3.3Vの場合に限ります。Arduino UNOでは出来ません。[[BR]]
+
+{{{
+#!c
+#define SLAVE 10
+}}}
+SLAVEの定義は、SPIのスレーブセレクトにデジタルの何番を使うかを決めています。
+
+※このスケッチはArduinoIDE付属のSPIライブラリを使用しています。
+
+=== max31855_example.pde (Arduino 1.0付属SPIライブラリ対応版) ===
+{{{
+#!c
+// K型熱電対温度センサモジュールキット(SPI接続)MAX31855使用(3.3V版)サンプルスケッチ
+// switch-science 2012.2.8
+
+#include "SPI.h"
+
+/*
+// Arduinoボードの電源電圧が3.3Vの場合、
+// 以下のマクロを有効にしてモジュールを直挿しできます。
+#define VCC  8
+#define GND  9
+*/
+#define SLAVE 10
+
+byte enabled = 255;
+
+void SPI_disable() {
+  if(enabled != 255) {
+    digitalWrite(enabled,HIGH);
+    enabled = 255;
+  }
+}
+void SPI_enable(byte slaveselecter) {
+  SPI_disable();
+  digitalWrite(slaveselecter,LOW);
+  enabled = slaveselecter;
+}
+
+byte SPI_read() {
+  return SPI.transfer(0x00);
+}
+
+void setup() {
+#ifdef GND
+  pinMode(GND, OUTPUT);
+  digitalWrite(GND, LOW); 
+#endif
+#ifdef VCC
+  pinMode(VCC, OUTPUT);
+  digitalWrite(VCC, HIGH);
+#endif
+  pinMode(SLAVE,OUTPUT);
+  digitalWrite(SLAVE,HIGH);
+
+  Serial.begin(9600);
+  SPI.begin();
+  SPI.setBitOrder(MSBFIRST);
+  SPI.setClockDivider(SPI_CLOCK_DIV4);
+  SPI.setDataMode(SPI_MODE0);
+}
+
+void loop() {
+  unsigned int thermocouple; // 14-Bit Thermocouple Temperature Data + 2-Bit
+  unsigned int internal; // 12-Bit Internal Temperature Data + 4-Bit
+  float disp; // display value 
+
+  delay(500);
+  SPI_enable(SLAVE);
+  thermocouple = (unsigned int)SPI_read() << 8;
+  thermocouple |= (unsigned int)SPI_read() ;
+  internal = (unsigned int)SPI_read() << 8;
+  internal |= (unsigned int)SPI_read();
+  SPI_disable();
+
+  if((thermocouple & 0x0001) != 0) {
+    Serial.print("ERROR: ");
+    if ((internal & 0x0004) !=0) {
+      Serial.print("Short to Vcc, ");
+    }
+    if ((internal & 0x0002) !=0) {
+      Serial.print("Short to GND, ");
+    }
+    if ((internal & 0x0001) !=0) {
+      Serial.print("Open Circuit, ");
+    }    
+    Serial.println("");
+  } else {
+    if((thermocouple & 0x8000) == 0){ // 0℃以上
+      disp = (thermocouple >> 2) * 0.25;
+    } else {                          // 0℃未満
+      disp = (0x3fff - (thermocouple >> 2) + 1)  * -0.25;
+    }
+    Serial.print(thermocouple,HEX);
+    Serial.print(" : ");
+    Serial.print(disp);
+
+    Serial.print(" // ");
+    
+    if((internal & 0x8000) == 0){ // 0℃以上
+      disp = (internal >> 4) * 0.0625;
+    } else {                          // 0℃未満
+      disp = (((0xffff - internal) >> 4) + 1)  * -0.0625;
+    }
+    Serial.print(internal,HEX);
+    Serial.print(" : ");
+    Serial.print(disp);
+    
+    Serial.println("");    
+  }
+}
+}}}