wiki:PCA9626B

LEDスティックボード PCA9626B の使い方

PCA9626B LEDスティックボードの使い方説明とArduino用サンプルスケッチです。

メーカーからデータシート(pdf)が公開されています。

PCA9626BはLEDを最大24個独立して光らせることができます。 16個のLEDを制御できる類似IC(PCA9622DR I2C 16ch LEDドライバ基板)もあります。

本製品ではフルカラーLEDに3chずつ接続し8個のフルカラーLEDを自由に制御できます。


内蔵機能

商品ページより一部抜粋したものを載せます。

  • 動作電圧 3.3V~5.5V
  • 24ch の独立したLEDポート
  • LEDポートのアウトプットイネーブル機能を搭載
  • 各ポートはon/offおよび256段階(8bit)のPWM階調制御が可能
  • 各ポートの独立制御/グループ制御が可能
  • 基板上に、8つのフルカラーLED を搭載

使い方

本製品はI2Cで接続されます。下に実体配線図を示します。

図では基板の左側に接続していますが、右側にも同じように接続可能な端子が出ています。 これを利用して、本基板を横につなげていくことも可能です。

本製品にはI2C通信時のプルアップ用抵抗は実装されていません。
ピンヘッダと合わせて各自で実装してください。
プルアップ抵抗はR25とR26に1608サイズの10kΩ程度のチップ抵抗をはんだ付けしてください。
また、ArduinoのWireライブラリを使用する場合は内蔵プルアップが有効になりますので、プルアップ抵抗を省略してもかまいません。

通信方法

I2C通信のアドレスは、Arduino向けの7bit表記で0x40です。これは基板上のジャンパ(SJ7~SJ1)で変更できます。

下にデータシートより送信プロトコル図を引用します。

スレーブアドレスを送信した後にデータを書き込み始めるアドレスを送信します。

この際、内部の自動インクリメントに関する設定を同時に送信する必要があります。

送信するデータは上位1bit(AIF)が設定用、下位6bitが書き込み先レジスタアドレスになります。

下に設定表を和訳したものを載せます。

AIFAI1AI0機能
000自動インクリメント機能無効
100全レジスタ領域に対して自動インクリメント機能有効
101輝度制御レジスタに対してのみ自動インクリメント機能有効(ロールオーバーも当該レジスタ内部のみ)
110点滅制御、CHASE機能レジスタに対してのみ自動インクリメント機能有効(ロールオーバーも当該レジスタ内部のみ)
111輝度制御、点滅制御、CHASE機能レジスタに対してのみ自動インクリメント機能有効(ロールオーバーも当該レジスタ内部のみ)

この際、AI1およびAI0はMODE1レジスタの内容が適応されます。

これ以外の設定状態は予約済みとなっているため使用しないでください。

例えば、初期化の際には(AIF,AI1,AI0)=(1,0,0)にして全領域に対してデータを書き込み、 運用時はMODE1レジスタ内部の(AI1,AI0)を(0,1)にして輝度以外の状態の不用意な変更を避けるなどといった運用があります。

I2C通信時に送信数レジスタアドレスと、各設定に対応したビットをORにかけるなどの実装が考えられます。 例についてはページ下部のサンプルスケッチを御覧ください。

受信に関しても、同様にインクリメントに関する設定を行ってください。

設定内容

内蔵の調光機能などの説明をします。

また、MODE1レジスタ内部にSLEEP機能ビットが存在しています。

起動時では標準で機能ONとなっているので、 初期化の際にOFFにする必要があります。

調光

LED一つごとに調光用のレジスタが8bit分が用意されています。 0~255の256段階で輝度を制御できます。 輝度は (レジスタ内容)/256 となります。

詳しくはデータシートp13ページを参照してください。

点滅

MODE2レジスタ内部のDMBLINKビットの状態で動作が変化します。 全体での点滅を有効にする際はこのビットを1にセットしてください。

  • 0にセットされている場合

点滅はしません。輝度は上記の調光の際の設定が適応されます。 詳しくはデータシートp14を参照してください。

  • 1にセットされている場合

点滅します。点滅のデューティー比と点滅の周期を個別に設定できます。

デューティー比は上記調光と同じように周期の256分割単位で調整できます。 周期は41msから10.73sの間で調整できます。 用意されている8bitの周期用レジスタに対して (レジスタ内容+1)/24 を周期とします。

例えば、2秒周期で光らせるには、設定用レジスタに対して0x2F(=47)を書き込みます。 詳しくはデータシートp14を参照してください。

CHASE機能

LEDの点灯を一括で制御できる機能です。 例えば右端から順番に点灯させたり、両端から中心に向かって順番に光らせたりなどといった事が可能です。

ただし、本製品ではフルカラーLEDに接続されているので、色をつけたまま順番に光らせるには工夫が必要となります。

詳しくはデータシートp15~21を参照してください。

点灯

24個のLEDに対して個別に点灯/調光/点滅の機能のON/OFFが設定できます。 各LEDに対して2bitが割り当てられてています。

この機能はCHASE機能と独立して働きます。

2bit目1bit目機能
00消灯
01点灯/調光と点滅は無効
10点灯/調光のみ有効
11点灯/調光と点滅が有効

その他

プログラム上でサブI2Cアドレスを変更することができます。 サブI2Cアドレスに応答するかどうかを設定することができます。

よって、同じICを大量に接続しても、プログラム次第で別個に点灯を制御することができます。

サンプルスケッチ

Arduino用のサンプルスケッチを載せます。(GitHub)

10秒間、8つのフルカラーLEDが2秒周期で点滅します。

その後、内蔵のCHASEモードを利用したデモに入ります。

以上の動作を繰り返します。

/*******************************************************************************
// SWITCHSCIENCE wiki -- http://trac.switch-science.com/
// PCA9626B Arduino Sample
*******************************************************************************/
#include <Wire.h>

#define PCA9626B_ADDR 0x40 // in 7bit for Arduino


#define MODE1 0x00
#define MODE2 0x01
#define PWM0 0x02
#define PWM1 0x03
#define PWM2 0x04
#define PWM3 0x05
#define PWM4 0x06
#define PWM5 0x07
#define PWM6 0x08
#define PWM7 0x09
#define PWM8 0x0A
#define PWM9 0x0B
#define PWM10 0x0C
#define PWM11 0x0D
#define PWM12 0x0E
#define PWM13 0x0F
#define PWM14 0x10
#define PWM15 0x11
#define PWM16 0x12
#define PWM17 0x13
#define PWM18 0x14
#define PWM19 0x15
#define PWM20 0x16
#define PWM21 0x17
#define PWM22 0x18
#define PWM23 0x19
#define GRPPWM 0x1A
#define GRPFREQ 0x1B
#define CHASE 0x1C
#define LEDOUT0 0x1D
#define LEDOUT1 0x1E
#define LEDOUT2 0x1F
#define LEDOUT3 0x20
#define LEDOUT4 0x21
#define LEDOUT5 0x22
#define SUBADR1 0x23
#define SUBADR2 0x24
#define SUBADR3 0x25
#define ALLCALLADR 0x26

#define AI_ALLEN  B10000000

#define AI_BRI_EN B00100000
#define AI_CHASE_EN B01000000

int chase  =0x00;
int chaseMode;

int dmblink_off = B00000101;
int dmblink_on = B00100101;


void datasend(int,int,int *,int);
void dataread(int,int,int *,int);

int ledOut[6];
int ledPWM[24];
int initdata[2];
void setup()
{
  Serial.begin(9600);
  Wire.begin();

  // 初期化
  initdata[0] = B10000001;// 4bit目のデフォルトはSLEEP=1
  initdata[1] = B00000101;// 5bit目のDMBLNK=1で全体点滅を有効/インクリメント機能ONの時は全レジスタ領域が対象
  datasend(PCA9626B_ADDR, MODE1 | AI_ALLEN, initdata, 2); // 全領域インクリメント

  // 調光用デューティー比の設定
  ledPWM[0]  = 0xFF; // Blue
  ledPWM[1]  = 0xFF; // Green
  ledPWM[2]  = 0xFF; // Red

  ledPWM[3] = 0x00; // Blue
  ledPWM[4] = 0xFF; // Green
  ledPWM[5] = 0x00; // Red

  ledPWM[6] = 0xFF; // Blue
  ledPWM[7] = 0x00; // Green
  ledPWM[8] = 0x00; // Red

  ledPWM[9] = 0x00; // Blue
  ledPWM[10] = 0x00; // Green
  ledPWM[11] = 0xFF; // Red

  ledPWM[12] = 0xFF; // Blue
  ledPWM[13] = 0xFF; // Green
  ledPWM[14] = 0x00; // Red

  ledPWM[15] = 0x00; // Blue
  ledPWM[16] = 0xFF; // Green
  ledPWM[17] = 0xFF; // Red

  ledPWM[18] = 0xFF; // Blue
  ledPWM[19] = 0x00; // Green
  ledPWM[20] = 0xFF; // Red

  ledPWM[21] = 0xFF; // Blue
  ledPWM[22] = 0xFF; // Green
  ledPWM[23] = 0xFF; // Red

  datasend(PCA9626B_ADDR, PWM0 | AI_ALLEN,ledPWM,24);

  // 全体点滅の設定
  int grp_pwm = 0x80; // 5:5
  datasend(PCA9626B_ADDR, GRPPWM,&grp_pwm,1);
  int grp_freq = 0x2F; // (0x2F+1)/24 秒周期 = 2秒周期
  datasend(PCA9626B_ADDR, GRPFREQ,&grp_freq,1);

  // CHASEモード初期化
  int chase_init = 0x00;
  datasend(PCA9626B_ADDR, CHASE,&chase_init,1);

  // LED出力設定
  //ledOut[0]= B01010101;  // LEDは個別調光に影響されない、つまり全色点灯し白色に見える
  ledOut[0]= B11111111;  // LEDは個別調光と全体の点滅(PWM)に影響される
  ledOut[1] = B11111111; // よって色の制御ができる
  ledOut[2] = B11111111;
  ledOut[3] = B11111111;
  ledOut[4] = B11111111;
  ledOut[5] = B11111111;
  datasend(PCA9626B_ADDR,LEDOUT0 | AI_ALLEN,ledOut,6);

  Serial.println("LED turned ON, PWM, etc...");
}

void loop()
{
  switch(chaseMode)
  {
    case 1: // CHASE機能有効
        // 全体点滅機能とCHASE機能は同時になされます
        // 見やすくするためにDMBLNKをOFFにしておきます
        datasend(PCA9626B_ADDR,MODE2, &dmblink_off,1);

        // 調光機能も有効になっているので見やすくするために全LEDを強制点灯させます
        ledOut[0] = B01010101;
        ledOut[1] = B01010101;
        ledOut[2] = B01010101;
        ledOut[3] = B01010101;
        ledOut[4] = B01010101;
        ledOut[5] = B01010101;
        datasend(PCA9626B_ADDR,LEDOUT0 | AI_ALLEN,ledOut,6);

        // CHSEモードの点灯の種類をすべて表示します
        for(chase=0;chase<0x90;chase++)
        {
          datasend(PCA9626B_ADDR,CHAS,&chase,1);
          delay(500);
        }
        // CHASEモード無効化
        chaseMode = 0;
        break;

    case 0: // CHASE機能無効
        // LEDの調光機能、全体点灯をONにし、色の制御を有効にします
        datasend(PCA9626B_ADDR,MODE2, &dmblink_on,1);
        ledOut[0] = B11111111;
        ledOut[1] = B11111111;
        ledOut[2] = B11111111;
        ledOut[3] = B11111111;
        ledOut[4] = B11111111;
        ledOut[5] = B11111111;
        datasend(PCA9626B_ADDR,LEDOUT0 | AI_ALLEN,ledOut,6);
        // 点滅機能はPCA9626内蔵機能なのでloop部分は何もせずとも点滅します
        delay(10000);
        // CHASEモード有効化
        chaseMode = 1;
        break;

    default:
        break;
  }
}



void datasend(int id,int reg,int *data,int datasize)
{
  Wire.beginTransmission(id);
  Wire.write(reg);
  for(int i=0;i<datasize;i++)
  {
    Wire.write(data[i]);
  }
  Wire.endTransmission();
}

void dataread(int id,int reg,int *data,int datasize)
{
  Wire.beginTransmission(id);
  Wire.write(reg);
  Wire.endTransmission(false);
  Wire.requestFrom(id, datasize, false);
  for(int i=0;i<datasize;i++)
  {
    data[i] = Wire.read();
  }
  Wire.endTransmission(true);
}
Last modified 22 months ago Last modified on Feb 16, 2016 3:33:30 PM

Attachments (4)

Download all attachments as: .zip